.版本 2
.支持库 eAPI
.支持库 iext
.程序集 窗口程序集1
.子程序 _按钮3_被单击
打开指定网址 (“”)
.子程序 _时钟1_周期事件
游戏窗口句柄 ＝ 窗口_取句柄_模糊 (“大家来找茬”, )
.如果 (游戏窗口句柄 ＝ 0)
透明标签1.标题 ＝ “游戏未启动”
.否则
透明标签1.标题 ＝ “游戏已启动”
.如果结束
游戏窗口位置 ＝ 窗口_取位置和大小 (游戏窗口句柄)
.子程序 _按钮1_被单击
载入 (窗口1, _启动窗口, 假)
窗口1.左边 ＝ 游戏窗口位置.左边 ＋ 515
窗口1.顶边 ＝ 游戏窗口位置.顶边 ＋ 190
_启动窗口.左边 ＝ 游戏窗口位置.左边 ＋ 游戏窗口位置.宽度 ＋ 5
_启动窗口.顶边 ＝ 游戏窗口位置.顶边 ＋ 50
按钮2.禁止 ＝ 假
按钮4.禁止 ＝ 假
选择框1.禁止 ＝ 假
.子程序 _按钮2_被单击
时钟2.时钟周期 ＝ 0
选择框1.选中 ＝ 假
选择框1.禁止 ＝ 真
窗口1.销毁 ()
按钮2.禁止 ＝ 真
按钮4.禁止 ＝ 真
.子程序 _按钮4_被单击
.局部变量 r红, 整数型, , , 原图字集中的红色部分
.局部变量 g绿, 整数型, , , 原图字集中的绿色部分
.局部变量 b兰, 整数型, , , 原图字集中的蓝色部分
.局部变量 x, 整数型, , , 绿颜色处于文件图像的第56位之后,这样从56位开始进行操作,每间隔3位都是处理绿色
.局部变量 y, 整数型, , , 兰颜色处于文件图像的第55位之后,这样从55位开始进行操作,每间隔3位都是处理兰色
.局部变量 z, 整数型, , , 红颜色处于文件图像的第57位之后,这样从57位开始进行操作,每间隔3位都是处理红色
.局部变量 原图字集, 字节集, , , 将原图片作为字节集读入内容中处理
.局部变量 比照字集, 字节集, , , 将比照图片作为字节集读入内容中处理
.局部变量 新图字集, 字节集, , , 将对比后的内容生成到这个内容字节集中,以后再一次性显示
.局部变量 r红1, 整数型, , , 比照图字集中的红色部分
.局部变量 g绿1, 整数型, , , 比照图字集中的绿色部分
.局部变量 b兰1, 整数型, , , 比照图字集中的蓝色部分
.局部变量 纠正位, 整数型, , , 因为图象数据中的每一个扫描行字节数必须为4的倍数，所以对图象宽度进行修正
.局部变量 容错率, 整数型, , , 容错率正值-用于容错率计算,这样对于JPEG类的图片来说可以去除干扰.
.局部变量 负容错率, 整数型, , , 容错率负值-用于容错率计算,范围在0-255之间较好!
.局部变量 计算值, 整数型, , , 将原图三原色数值相加后减去比照图的三原色数值-用于容错率计算
.局部变量 图片1, 字节集
.局部变量 图片2, 字节集
窗口1.画板1.可视 ＝ 假
窗口1.画板1.底图 ＝ { }
图片1 ＝ 图片_屏幕区域截图 (游戏窗口位置.左边 ＋ 6, 游戏窗口位置.顶边 ＋ 190, 500, 450)
图片2 ＝ 图片_屏幕区域截图 (游戏窗口位置.左边 ＋ 515, 游戏窗口位置.顶边 ＋ 190, 500, 450)
窗口1.画板1.可视 ＝ 真
容错率 ＝ 10 ' 从编辑框中取得容错率,这样对于JPEG类的图片来说,有一定的容错较好.
负容错率 ＝ －容错率 ' 这两个都是容错的前后范围
原图字集 ＝ 图片1 ' 先将两幅图读为字节集在内存中处理,这样较快速
比照字集 ＝ 图片2 ' 先将两幅图读为字节集在内存中处理,这样较快速
新图字集 ＝ 图片2 ' 这里是将结果图片初始化一下.否则会因没有放入数据,数组下标会超出
x ＝ 56 ' 绿颜色处于文件图像的第56位之后,这样从56位开始进行操作,每间隔3位都是处理绿色
y ＝ 55 ' 兰颜色处于文件图像的第55位之后,这样从55位开始进行操作,每间隔3位都是处理兰色
z ＝ 57 ' 红颜色处于文件图像的第57位之后,这样从57位开始进行操作,每间隔3位都是处理红色
纠正位 ＝ 选择 (500 × 3 ％ 4 ＝ 0, 0, 4 － 500 × 3 ％ 4) ' 利用图像宽度计算纠正位为几个字节
.计次循环首 (600, ) ' 字节集的55位后是各扫描行的数据,用图片的高可以得到扫描行的总数
.计次循环首 (500, ) ' 每一个扫描行是由各像素点（三个字节）数据组成，可以用图片的宽度得像素的数目
r红 ＝ 原图字集 [z] ' 在原图中,从第57位开始,每三位读一次,读出的是红色的数据
g绿 ＝ 原图字集 [x] ' 在原图中,从第56位开始,每三位读一次,读出的是绿色的数据
b兰 ＝ 原图字集 [y] ' 在原图中,从第55位开始,每三位读一次,读出的是兰色的数据
r红1 ＝ 比照字集 [z] ' 在比照图中,从第57位开始,每三位读一次,读出的是红色的数据
g绿1 ＝ 比照字集 [x] ' 在比照图中,从第56位开始,每三位读一次,读出的是绿色的数据
b兰1 ＝ 比照字集 [y] ' 在比照图中,从第55位开始,每三位读一次,读出的是兰色的数据
计算值 ＝ r红 ＋ g绿 ＋ b兰 － (r红1 ＋ g绿1 ＋ b兰1)
.如果 (计算值 ＞ 容错率 或 计算值 ＜ 负容错率) ' 比较两张图-原图片与比照图片的三原色各有什么不同,如果不同就显示不同的地方,否则用白颜色填充
新图字集 [z] ＝ r红1 ' 新图片取到以上两图不同的地方就取值,以便于显示不同处.这里取的是其中之一颜色
新图字集 [x] ＝ g绿1 ' 新图片取到以上两图不同的地方就取值,以便于显示不同处.这里取的是其中之一颜色
新图字集 [y] ＝ b兰1 ' 新图片取到以上两图不同的地方就取值,以便于显示不同处.这里取的是其中之一颜色
.否则
新图字集 [z] ＝ 255 ' 如果是相同处,就用白颜色填充
新图字集 [x] ＝ 255 ' 如果是相同处,就用白颜色填充
新图字集 [y] ＝ 255 ' 如果是相同处,就用白颜色填充
.如果结束
x ＝ x ＋ 3 ' 前面已经说了,每间隔三位是一种颜色,现在就是其中一种颜色的位置进3位
y ＝ y ＋ 3 ' 前面已经说了,每间隔三位是一种颜色,现在就是其中一种颜色的位置进3位
z ＝ z ＋ 3 ' 前面已经说了,每间隔三位是一种颜色,现在就是其中一种颜色的位置进3位
.计次循环尾 ()
x ＝ x ＋ 纠正位 ' 因为每一扫描行的字节数必须是4的整数倍，所以加入纠正位
y ＝ y ＋ 纠正位 ' 因为每一扫描行的字节数必须是4的整数倍，所以加入纠正位
z ＝ z ＋ 纠正位 ' 因为每一扫描行的字节数必须是4的整数倍，所以加入纠正位
.计次循环尾 ()
窗口1.画板1.底图 ＝ 新图字集 ' 通过上述取到了不同内容的新图片字节集,这时就可以显示出来了,字节集在内容中处理,速度非常快.”
.子程序 __启动窗口_创建完毕
窗口_总在最前 (_启动窗口.取窗口句柄 (), 真)
.子程序 _选择框1_被单击
.如果真 (选择框1.选中 ＝ 真)
选择框1.选中 ＝ 假
时钟2.时钟周期 ＝ 0
.如果真结束
.如果真 (选择框1.选中 ＝ 假)
选择框1.选中 ＝ 真
时钟2.时钟周期 ＝ 500
.如果真结束
.子程序 _时钟2_周期事件
_按钮4_被单击 ()
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------
.版本 2
.程序集 窗口程序集2
.子程序 _窗口1_创建完毕
窗口_置透明度 (窗口1.取窗口句柄 (), 180, , 真)
窗口_总在最前 (窗口1.取窗口句柄 (), 真)
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------
.版本 2
.全局变量 游戏窗口句柄, 整数型
.全局变量 游戏窗口位置, 精易_矩形
